Newer
Older
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
MODULE zpshde
!!======================================================================
!! *** MODULE zpshde ***
!! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
!!======================================================================
!! History : OPA ! 2002-04 (A. Bozec) Original code
!! NEMO 1.0 ! 2002-08 (G. Madec E. Durand) Optimization and Free form
!! - ! 2004-03 (C. Ethe) adapted for passive tracers
!! 3.3 ! 2010-05 (C. Ethe, G. Madec) merge TRC-TRA
!! 3.6 ! 2014-11 (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
!!======================================================================
!!----------------------------------------------------------------------
!! zps_hde : Horizontal DErivative of T, S and rd at the last
!! ocean level (Z-coord. with Partial Steps)
!!----------------------------------------------------------------------
USE oce ! ocean: dynamics and tracers variables
USE dom_oce ! domain: ocean variables
USE domutl, ONLY : is_tile
USE phycst ! physical constants
USE eosbn2 ! ocean equation of state
USE in_out_manager ! I/O manager
USE lbclnk ! lateral boundary conditions (or mpp link)
USE lib_mpp ! MPP library
USE timing ! Timing
IMPLICIT NONE
PRIVATE
PUBLIC zps_hde ! routine called by step.F90
PUBLIC zps_hde_isf ! routine called by step.F90
!! * Substitutions
# include "do_loop_substitute.h90"
# include "domzgr_substitute.h90"
!!----------------------------------------------------------------------
!! NEMO/OCE 4.0 , NEMO Consortium (2018)
!! $Id: zpshde.F90 14834 2021-05-11 09:24:44Z hadcv $
!! Software governed by the CeCILL license (see ./LICENSE)
!!----------------------------------------------------------------------
CONTAINS
SUBROUTINE zps_hde( kt, Kmm, kjpt, pta, pgtu, pgtv, &
& prd, pgru, pgrv )
!!
INTEGER , INTENT(in ) :: kt ! ocean time-step index
INTEGER , INTENT(in ) :: Kmm ! ocean time level index
INTEGER , INTENT(in ) :: kjpt ! number of tracers
REAL(wp), DIMENSION(:,:,:,:), INTENT(in ) :: pta ! 4D tracers fields
REAL(wp), DIMENSION(:,:,:) , INTENT( out) :: pgtu, pgtv ! hor. grad. of ptra at u- & v-pts
REAL(wp), DIMENSION(:,:,:) , INTENT(in ), OPTIONAL :: prd ! 3D density anomaly fields
REAL(wp), DIMENSION(:,:) , INTENT( out), OPTIONAL :: pgru, pgrv ! hor. grad of prd at u- & v-pts (bottom)
!
INTEGER :: itrd, itgr
!!
IF( PRESENT(prd) ) THEN ; itrd = is_tile(prd) ; ELSE ; itrd = 0 ; ENDIF
IF( PRESENT(pgru) ) THEN ; itgr = is_tile(pgru) ; ELSE ; itgr = 0 ; ENDIF
CALL zps_hde_t( kt, Kmm, kjpt, pta, is_tile(pta), pgtu, pgtv, is_tile(pgtu), &
& prd, itrd, pgru, pgrv, itgr )
END SUBROUTINE zps_hde
SUBROUTINE zps_hde_t( kt, Kmm, kjpt, pta, ktta, pgtu, pgtv, ktgt, &
& prd, ktrd, pgru, pgrv, ktgr )
!!----------------------------------------------------------------------
!! *** ROUTINE zps_hde ***
!!
!! ** Purpose : Compute the horizontal derivative of T, S and rho
!! at u- and v-points with a linear interpolation for z-coordinate
!! with partial steps.
!!
!! ** Method : In z-coord with partial steps, scale factors on last
!! levels are different for each grid point, so that T, S and rd
!! points are not at the same depth as in z-coord. To have horizontal
!! gradients again, we interpolate T and S at the good depth :
!! Linear interpolation of T, S
!! Computation of di(tb) and dj(tb) by vertical interpolation:
!! di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
!! dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
!! This formulation computes the two cases:
!! CASE 1 CASE 2
!! k-1 ___ ___________ k-1 ___ ___________
!! Ti T~ T~ Ti+1
!! _____ _____
!! k | |Ti+1 k Ti | |
!! | |____ ____| |
!! ___ | | | ___ | | |
!!
!! case 1-> e3w(i+1,:,:,Kmm) >= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) >= e3w(:,j,:,Kmm) ) then
!! t~ = t(i+1,j ,k) + (e3w(i+1,j,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j,k,Kmm)
!! ( t~ = t(i ,j+1,k) + (e3w(i,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i,j+1,k,Kmm) )
!! or
!! case 2-> e3w(i+1,:,:,Kmm) <= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) <= e3w(:,j,:,Kmm) ) then
!! t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
!! ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
!! Idem for di(s) and dj(s)
!!
!! For rho, we call eos which will compute rd~(t~,s~) at the right
!! depth zh from interpolated T and S for the different formulations
!! of the equation of state (eos).
!! Gradient formulation for rho :
!! di(rho) = rd~ - rd(i,j,k) or rd(i+1,j,k) - rd~
!!
!! ** Action : compute for top interfaces
!! - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
!! - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
!!----------------------------------------------------------------------
INTEGER , INTENT(in ) :: kt ! ocean time-step index
INTEGER , INTENT(in ) :: Kmm ! ocean time level index
INTEGER , INTENT(in ) :: kjpt ! number of tracers
INTEGER , INTENT(in ) :: ktta, ktgt, ktrd, ktgr
REAL(wp), DIMENSION(A2D_T(ktta),JPK,KJPT), INTENT(in ) :: pta ! 4D tracers fields
REAL(wp), DIMENSION(A2D_T(ktgt) ,KJPT), INTENT( out) :: pgtu, pgtv ! hor. grad. of ptra at u- & v-pts
REAL(wp), DIMENSION(A2D_T(ktrd),JPK ), INTENT(in ), OPTIONAL :: prd ! 3D density anomaly fields
REAL(wp), DIMENSION(A2D_T(ktgr) ), INTENT( out), OPTIONAL :: pgru, pgrv ! hor. grad of prd at u- & v-pts (bottom)
!
INTEGER :: ji, jj, jn ! Dummy loop indices
INTEGER :: iku, ikv, ikum1, ikvm1 ! partial step level (ocean bottom level) at u- and v-points
REAL(wp) :: ze3wu, ze3wv, zmaxu, zmaxv ! local scalars
REAL(wp), DIMENSION(A2D(nn_hls)) :: zri, zrj, zhi, zhj ! NB: 3rd dim=1 to use eos
REAL(wp), DIMENSION(A2D(nn_hls),kjpt) :: zti, ztj !
!!----------------------------------------------------------------------
!
IF( ln_timing ) CALL timing_start( 'zps_hde')
!
pgtu(:,:,:) = 0._wp ; zti (:,:,:) = 0._wp ; zhi (:,:) = 0._wp
pgtv(:,:,:) = 0._wp ; ztj (:,:,:) = 0._wp ; zhj (:,:) = 0._wp
!
DO jn = 1, kjpt !== Interpolation of tracers at the last ocean level ==!
!
DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 ) ! Gradient of density at the last level
iku = mbku(ji,jj) ; ikum1 = MAX( iku - 1 , 1 ) ! last and before last ocean level at u- & v-points
ikv = mbkv(ji,jj) ; ikvm1 = MAX( ikv - 1 , 1 ) ! if level first is a p-step, ik.m1=1
!!gm BUG ? when applied to before fields, e3w(:,:,k,Kbb) should be used....
ze3wu = e3w(ji+1,jj ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
ze3wv = e3w(ji ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
!
! i- direction
IF( ze3wu >= 0._wp ) THEN ! case 1
zmaxu = ze3wu / e3w(ji+1,jj,iku,Kmm)
! interpolated values of tracers
zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
! gradient of tracers
pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
ELSE ! case 2
zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
! interpolated values of tracers
zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
! gradient of tracers
pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
ENDIF
!
! j- direction
IF( ze3wv >= 0._wp ) THEN ! case 1
zmaxv = ze3wv / e3w(ji,jj+1,ikv,Kmm)
! interpolated values of tracers
ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
! gradient of tracers
pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
ELSE ! case 2
zmaxv = -ze3wv / e3w(ji,jj,ikv,Kmm)
! interpolated values of tracers
ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
! gradient of tracers
pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
ENDIF
END_2D
END DO
!
IF (nn_hls==1) CALL lbc_lnk( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp ) ! Lateral boundary cond.
!
IF( PRESENT( prd ) ) THEN !== horizontal derivative of density anomalies (rd) ==! (optional part)
pgru(:,:) = 0._wp
pgrv(:,:) = 0._wp ! depth of the partial step level
DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
iku = mbku(ji,jj)
ikv = mbkv(ji,jj)
ze3wu = e3w(ji+1,jj ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
ze3wv = e3w(ji ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
IF( ze3wu >= 0._wp ) THEN ; zhi(ji,jj) = gdept(ji ,jj,iku,Kmm) ! i-direction: case 1
ELSE ; zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm) ! - - case 2
ENDIF
IF( ze3wv >= 0._wp ) THEN ; zhj(ji,jj) = gdept(ji,jj ,ikv,Kmm) ! j-direction: case 1
ELSE ; zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm) ! - - case 2
ENDIF
END_2D
!
CALL eos( zti, zhi, zri ) ! interpolated density from zti, ztj
CALL eos( ztj, zhj, zrj ) ! at the partial step depth output in zri, zrj
!
DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 ) ! Gradient of density at the last level
iku = mbku(ji,jj)
ikv = mbkv(ji,jj)
ze3wu = e3w(ji+1,jj ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
ze3wv = e3w(ji ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
IF( ze3wu >= 0._wp ) THEN ; pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji ,jj ) - prd(ji,jj,iku) ) ! i: 1
ELSE ; pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj ) ) ! i: 2
ENDIF
IF( ze3wv >= 0._wp ) THEN ; pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj ) - prd(ji,jj,ikv) ) ! j: 1
ELSE ; pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj ) ) ! j: 2
ENDIF
END_2D
IF (nn_hls==1) CALL lbc_lnk( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp ) ! Lateral boundary conditions
!
END IF
!
IF( ln_timing ) CALL timing_stop( 'zps_hde')
!
END SUBROUTINE zps_hde_t
SUBROUTINE zps_hde_isf( kt, Kmm, kjpt, pta, pgtu, pgtv, pgtui, pgtvi, &
& prd, pgru, pgrv, pgrui, pgrvi )
!!
INTEGER , INTENT(in ) :: kt ! ocean time-step index
INTEGER , INTENT(in ) :: Kmm ! ocean time level index
INTEGER , INTENT(in ) :: kjpt ! number of tracers
REAL(wp), DIMENSION(:,:,:,:), INTENT(in ) :: pta ! 4D tracers fields
REAL(wp), DIMENSION(:,:,:) , INTENT( out) :: pgtu, pgtv ! hor. grad. of ptra at u- & v-pts
REAL(wp), DIMENSION(:,:,:) , INTENT( out) :: pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
REAL(wp), DIMENSION(:,:,:) , INTENT(in ), OPTIONAL :: prd ! 3D density anomaly fields
REAL(wp), DIMENSION(:,:) , INTENT( out), OPTIONAL :: pgru, pgrv ! hor. grad of prd at u- & v-pts (bottom)
REAL(wp), DIMENSION(:,:) , INTENT( out), OPTIONAL :: pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
!
INTEGER :: itrd, itgr, itgri
!!
IF( PRESENT(prd) ) THEN ; itrd = is_tile(prd) ; ELSE ; itrd = 0 ; ENDIF
IF( PRESENT(pgru) ) THEN ; itgr = is_tile(pgru) ; ELSE ; itgr = 0 ; ENDIF
IF( PRESENT(pgrui) ) THEN ; itgri = is_tile(pgrui) ; ELSE ; itgri = 0 ; ENDIF
CALL zps_hde_isf_t( kt, Kmm, kjpt, pta, is_tile(pta), pgtu, pgtv, is_tile(pgtu), pgtui, pgtvi, is_tile(pgtui), &
& prd, itrd, pgru, pgrv, itgr, pgrui, pgrvi, itgri )
END SUBROUTINE zps_hde_isf
SUBROUTINE zps_hde_isf_t( kt, Kmm, kjpt, pta, ktta, pgtu, pgtv, ktgt, pgtui, pgtvi, ktgti, &
& prd, ktrd, pgru, pgrv, ktgr, pgrui, pgrvi, ktgri )
!!----------------------------------------------------------------------
!! *** ROUTINE zps_hde_isf ***
!!
!! ** Purpose : Compute the horizontal derivative of T, S and rho
!! at u- and v-points with a linear interpolation for z-coordinate
!! with partial steps for top (ice shelf) and bottom.
!!
!! ** Method : In z-coord with partial steps, scale factors on last
!! levels are different for each grid point, so that T, S and rd
!! points are not at the same depth as in z-coord. To have horizontal
!! gradients again, we interpolate T and S at the good depth :
!! For the bottom case:
!! Linear interpolation of T, S
!! Computation of di(tb) and dj(tb) by vertical interpolation:
!! di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
!! dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
!! This formulation computes the two cases:
!! CASE 1 CASE 2
!! k-1 ___ ___________ k-1 ___ ___________
!! Ti T~ T~ Ti+1
!! _____ _____
!! k | |Ti+1 k Ti | |
!! | |____ ____| |
!! ___ | | | ___ | | |
!!
!! case 1-> e3w(i+1,j,k,Kmm) >= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) >= e3w(i,j,k,Kmm) ) then
!! t~ = t(i+1,j ,k) + (e3w(i+1,j ,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j ,k,Kmm)
!! ( t~ = t(i ,j+1,k) + (e3w(i ,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i ,j+1,k,Kmm) )
!! or
!! case 2-> e3w(i+1,j,k,Kmm) <= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) <= e3w(i,j,k,Kmm) ) then
!! t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j ,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
!! ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i ,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
!! Idem for di(s) and dj(s)
!!
!! For rho, we call eos which will compute rd~(t~,s~) at the right
!! depth zh from interpolated T and S for the different formulations
!! of the equation of state (eos).
!! Gradient formulation for rho :
!! di(rho) = rd~ - rd(i,j,k) or rd(i+1,j,k) - rd~
!!
!! For the top case (ice shelf): As for the bottom case but upside down
!!
!! ** Action : compute for top and bottom interfaces
!! - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
!! - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
!!----------------------------------------------------------------------
INTEGER , INTENT(in ) :: kt ! ocean time-step index
INTEGER , INTENT(in ) :: Kmm ! ocean time level index
INTEGER , INTENT(in ) :: kjpt ! number of tracers
INTEGER , INTENT(in ) :: ktta, ktgt, ktgti, ktrd, ktgr, ktgri
REAL(wp), DIMENSION(A2D_T(ktta),JPK,KJPT), INTENT(in ) :: pta ! 4D tracers fields
REAL(wp), DIMENSION(A2D_T(ktgt) ,KJPT), INTENT( out) :: pgtu, pgtv ! hor. grad. of ptra at u- & v-pts
REAL(wp), DIMENSION(A2D_T(ktgti) ,KJPT), INTENT( out) :: pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
REAL(wp), DIMENSION(A2D_T(ktrd),JPK ), INTENT(in ), OPTIONAL :: prd ! 3D density anomaly fields
REAL(wp), DIMENSION(A2D_T(ktgr) ), INTENT( out), OPTIONAL :: pgru, pgrv ! hor. grad of prd at u- & v-pts (bottom)
REAL(wp), DIMENSION(A2D_T(ktgri) ), INTENT( out), OPTIONAL :: pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
!
INTEGER :: ji, jj, jn ! Dummy loop indices
INTEGER :: iku, ikv, ikum1, ikvm1,ikup1, ikvp1 ! partial step level (ocean bottom level) at u- and v-points
REAL(wp) :: ze3wu, ze3wv, zmaxu, zmaxv ! temporary scalars
REAL(wp), DIMENSION(A2D(nn_hls)) :: zri, zrj, zhi, zhj ! NB: 3rd dim=1 to use eos
REAL(wp), DIMENSION(A2D(nn_hls),kjpt) :: zti, ztj !
!!----------------------------------------------------------------------
!
IF( ln_timing ) CALL timing_start( 'zps_hde_isf')
!
pgtu (:,:,:) = 0._wp ; pgtv (:,:,:) =0._wp
pgtui(:,:,:) = 0._wp ; pgtvi(:,:,:) =0._wp
zti (:,:,:) = 0._wp ; ztj (:,:,:) =0._wp
zhi (:,: ) = 0._wp ; zhj (:,: ) =0._wp
!
DO jn = 1, kjpt !== Interpolation of tracers at the last ocean level ==!
!
DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 )
iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 ) ! last and before last ocean level at u- & v-points
ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 ) ! if level first is a p-step, ik.m1=1
ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
!
! i- direction
IF( ze3wu >= 0._wp ) THEN ! case 1
zmaxu = ze3wu / e3w(ji+1,jj,iku,Kmm)
! interpolated values of tracers
zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
! gradient of tracers
pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
ELSE ! case 2
zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
! interpolated values of tracers
zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
! gradient of tracers
pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
ENDIF
!
! j- direction
IF( ze3wv >= 0._wp ) THEN ! case 1
zmaxv = ze3wv / e3w(ji,jj+1,ikv,Kmm)
! interpolated values of tracers
ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
! gradient of tracers
pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
ELSE ! case 2
zmaxv = -ze3wv / e3w(ji,jj,ikv,Kmm)
! interpolated values of tracers
ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
! gradient of tracers
pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
ENDIF
END_2D
END DO
!
IF (nn_hls==1) CALL lbc_lnk( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp ) ! Lateral boundary cond.
! horizontal derivative of density anomalies (rd)
IF( PRESENT( prd ) ) THEN ! depth of the partial step level
pgru(:,:)=0.0_wp ; pgrv(:,:)=0.0_wp ;
!
DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
iku = mbku(ji,jj)
ikv = mbkv(ji,jj)
ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
!
IF( ze3wu >= 0._wp ) THEN ; zhi(ji,jj) = gdept(ji ,jj,iku,Kmm) ! i-direction: case 1
ELSE ; zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm) ! - - case 2
ENDIF
IF( ze3wv >= 0._wp ) THEN ; zhj(ji,jj) = gdept(ji,jj ,ikv,Kmm) ! j-direction: case 1
ELSE ; zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm) ! - - case 2
ENDIF
END_2D
! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
! step and store it in zri, zrj for each case
CALL eos( zti, zhi, zri )
CALL eos( ztj, zhj, zrj )
DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
iku = mbku(ji,jj)
ikv = mbkv(ji,jj)
ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
IF( ze3wu >= 0._wp ) THEN ; pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji ,jj ) - prd(ji,jj,iku) ) ! i: 1
ELSE ; pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj ) ) ! i: 2
ENDIF
IF( ze3wv >= 0._wp ) THEN ; pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj ) - prd(ji,jj,ikv) ) ! j: 1
ELSE ; pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj ) ) ! j: 2
ENDIF
END_2D
IF (nn_hls==1) CALL lbc_lnk( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp ) ! Lateral boundary conditions
!
END IF
!
! !== (ISH) compute grui and gruvi ==!
!
DO jn = 1, kjpt !== Interpolation of tracers at the last ocean level ==! !
DO_2D( nn_hls, nn_hls-1, nn_hls, nn_hls-1 )
iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
!
! (ISF) case partial step top and bottom in adjacent cell in vertical
! cannot used e3w because if 2 cell water column, we have ps at top and bottom
! in this case e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm) is not the distance between Tj~ and Tj
! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
ze3wu = gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
ze3wv = gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm)
! i- direction
IF( ze3wu >= 0._wp ) THEN ! case 1
zmaxu = ze3wu / e3w(ji+1,jj,ikup1,Kmm)
! interpolated values of tracers
zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
! gradient of tracers
pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
ELSE ! case 2
zmaxu = - ze3wu / e3w(ji,jj,ikup1,Kmm)
! interpolated values of tracers
zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
! gradient of tracers
pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
ENDIF
!
! j- direction
IF( ze3wv >= 0._wp ) THEN ! case 1
zmaxv = ze3wv / e3w(ji,jj+1,ikvp1,Kmm)
! interpolated values of tracers
ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
! gradient of tracers
pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
ELSE ! case 2
zmaxv = - ze3wv / e3w(ji,jj,ikvp1,Kmm)
! interpolated values of tracers
ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
! gradient of tracers
pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
ENDIF
END_2D
!
END DO
IF (nn_hls==1) CALL lbc_lnk( 'zpshde', pgtui(:,:,:), 'U', -1.0_wp , pgtvi(:,:,:), 'V', -1.0_wp ) ! Lateral boundary cond.
IF( PRESENT( prd ) ) THEN !== horizontal derivative of density anomalies (rd) ==! (optional part)
!
pgrui(:,:) =0.0_wp; pgrvi(:,:) =0.0_wp;
DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
iku = miku(ji,jj)
ikv = mikv(ji,jj)
ze3wu = gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
ze3wv = gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm)
!
IF( ze3wu >= 0._wp ) THEN ; zhi(ji,jj) = gdept(ji ,jj,iku,Kmm) ! i-direction: case 1
ELSE ; zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm) ! - - case 2
ENDIF
IF( ze3wv >= 0._wp ) THEN ; zhj(ji,jj) = gdept(ji,jj ,ikv,Kmm) ! j-direction: case 1
ELSE ; zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm) ! - - case 2
ENDIF
END_2D
!
CALL eos( zti, zhi, zri ) ! interpolated density from zti, ztj
CALL eos( ztj, zhj, zrj ) ! at the partial step depth output in zri, zrj
!
DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
iku = miku(ji,jj)
ikv = mikv(ji,jj)
ze3wu = gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
ze3wv = gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm)
IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji ,jj ) - prd(ji,jj,iku) ) ! i: 1
ELSE ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj ,iku) - zri(ji,jj ) ) ! i: 2
ENDIF
IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji ,jj ) - prd(ji,jj,ikv) ) ! j: 1
ELSE ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji ,jj+1,ikv) - zrj(ji,jj ) ) ! j: 2
ENDIF
END_2D
IF (nn_hls==1) CALL lbc_lnk( 'zpshde', pgrui, 'U', -1.0_wp , pgrvi, 'V', -1.0_wp ) ! Lateral boundary conditions
!
END IF
!
IF( ln_timing ) CALL timing_stop( 'zps_hde_isf')
!
END SUBROUTINE zps_hde_isf_t
!!======================================================================
END MODULE zpshde