Newer
Older
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
MODULE p4zmicro
!!======================================================================
!! *** MODULE p4zmicro ***
!! TOP : PISCES Compute the sources/sinks for microzooplankton
!!======================================================================
!! History : 1.0 ! 2004 (O. Aumont) Original code
!! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90
!! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Quota model for iron
!!----------------------------------------------------------------------
!! p4z_micro : Compute the sources/sinks for microzooplankton
!! p4z_micro_init : Initialize and read the appropriate namelist
!!----------------------------------------------------------------------
USE oce_trc ! shared variables between ocean and passive tracers
USE trc ! passive tracers common variables
USE sms_pisces ! PISCES Source Minus Sink variables
USE p4zlim ! Co-limitations
USE p4zprod ! production
USE iom ! I/O manager
USE prtctl ! print control for debugging
IMPLICIT NONE
PRIVATE
!! * Shared module variables
PUBLIC p4z_micro ! called in p4zbio.F90
PUBLIC p4z_micro_init ! called in trcsms_pisces.F90
REAL(wp), PUBLIC :: part !: part of calcite not dissolved in microzoo guts
REAL(wp), PUBLIC :: xprefc !: microzoo preference for POC
REAL(wp), PUBLIC :: xprefn !: microzoo preference for nanophyto
REAL(wp), PUBLIC :: xprefd !: microzoo preference for diatoms
REAL(wp), PUBLIC :: xthreshdia !: diatoms feeding threshold for microzooplankton
REAL(wp), PUBLIC :: xthreshphy !: nanophyto threshold for microzooplankton
REAL(wp), PUBLIC :: xthreshpoc !: poc threshold for microzooplankton
REAL(wp), PUBLIC :: xthresh !: feeding threshold for microzooplankton
REAL(wp), PUBLIC :: resrat !: exsudation rate of microzooplankton
REAL(wp), PUBLIC :: mzrat !: microzooplankton mortality rate
REAL(wp), PUBLIC :: grazrat !: maximal microzoo grazing rate
REAL(wp), PUBLIC :: xkgraz !: Half-saturation constant of assimilation
REAL(wp), PUBLIC :: unass !: Non-assimilated part of food
REAL(wp), PUBLIC :: sigma1 !: Fraction of microzoo excretion as DOM
REAL(wp), PUBLIC :: epsher !: growth efficiency for grazing 1
REAL(wp), PUBLIC :: epshermin !: minimum growth efficiency for grazing 1
REAL(wp), PUBLIC :: xsigma !: Width of the grazing window
REAL(wp), PUBLIC :: xsigmadel !: Maximum additional width of the grazing window at low food density
!! * Substitutions
# include "do_loop_substitute.h90"
!!----------------------------------------------------------------------
!! NEMO/TOP 4.0 , NEMO Consortium (2018)
!! $Id: p4zmicro.F90 15459 2021-10-29 08:19:18Z cetlod $
!! Software governed by the CeCILL license (see ./LICENSE)
!!----------------------------------------------------------------------
CONTAINS
SUBROUTINE p4z_micro( kt, knt, Kbb, Krhs )
!!---------------------------------------------------------------------
!! *** ROUTINE p4z_micro ***
!!
!! ** Purpose : Compute the sources/sinks for microzooplankton
!! This includes ingestion and assimilation, flux feeding
!! and mortality. We use a passive prey switching
!! parameterization.
!! All living compartments smaller than microzooplankton
!! are potential preys of microzooplankton
!!
!! ** Method : - ???
!!---------------------------------------------------------------------
INTEGER, INTENT(in) :: kt ! ocean time step
INTEGER, INTENT(in) :: knt ! ???
INTEGER, INTENT(in) :: Kbb, Krhs ! time level indices
!
INTEGER :: ji, jj, jk
REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc
REAL(wp) :: zgraze , zdenom, zdenom2, zfact, zfood, zfoodlim, zbeta
REAL(wp) :: zepsherf, zepshert, zepsherq, zepsherv, zgrarsig, zgraztotc, zgraztotn, zgraztotf
REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
REAL(wp) :: zrespz, ztortz, zgrasratf, zgrasratn
REAL(wp) :: zgraznc, zgrazpoc, zgrazdc, zgrazpof, zgrazdf, zgraznf
REAL(wp) :: zsigma, zdiffdn, ztmp1, ztmp2, ztmp3, ztmptot, zproport
REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing, zfezoo
REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zzligprod
CHARACTER (len=25) :: charout
!!---------------------------------------------------------------------
!
IF( ln_timing ) CALL timing_start('p4z_micro')
!
IF (ln_ligand) THEN
ALLOCATE( zzligprod(jpi,jpj,jpk) )
zzligprod(:,:,:) = 0._wp
ENDIF
!
DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1)
zcompaz = MAX( ( tr(ji,jj,jk,jpzoo,Kbb) - 1.e-9 ), 0.e0 )
zfact = xstep * tgfunc2(ji,jj,jk) * zcompaz
! Proportion of diatoms that are within the size range
! accessible to microzooplankton.
zproport = min(1.0, exp(-1.1 * MAX(0., ( sized(ji,jj,jk) - 1.8 ))**0.8 ))
! linear mortality of mesozooplankton
! A michaelis menten modulation term is used to avoid extinction of
! microzooplankton at very low food concentrations. Mortality is
! enhanced in low O2 waters
! -----------------------------------------------------------------
zrespz = resrat * zfact * tr(ji,jj,jk,jpzoo,Kbb) / ( xkmort + tr(ji,jj,jk,jpzoo,Kbb) ) &
& + resrat * zfact * 3. * nitrfac(ji,jj,jk)
! Zooplankton quadratic mortality. A square function has been selected with
! to mimic predation and disease (density dependent mortality). It also tends
! to stabilise the model
! -------------------------------------------------------------------------
ztortz = mzrat * 1.e6 * zfact * tr(ji,jj,jk,jpzoo,Kbb) * (1. - nitrfac(ji,jj,jk))
! Computation of the abundance of the preys
! A threshold can be specified in the namelist
! Diatoms have a specific treatment. WHen concentrations
! exceed a certain value, diatoms are suppposed to be too
! big for microzooplankton.
! --------------------------------------------------------
zcompadi = zproport * MAX( ( tr(ji,jj,jk,jpdia,Kbb) - xthreshdia ), 0.e0 )
zcompaph = MAX( ( tr(ji,jj,jk,jpphy,Kbb) - xthreshphy ), 0.e0 )
zcompapoc = MAX( ( tr(ji,jj,jk,jppoc,Kbb) - xthreshpoc ), 0.e0 )
! Microzooplankton grazing
! The total amount of food is the sum of all preys accessible to mesozooplankton
! multiplied by their food preference
! A threshold can be specified in the namelist (xthresh). However, when food
! concentration is close to this threshold, it is decreased to avoid the
! accumulation of food in the mesozoopelagic domain
! -------------------------------------------------------------------------------
zfood = xprefn * zcompaph + xprefc * zcompapoc + xprefd * zcompadi
zfoodlim = MAX( 0. , zfood - min(xthresh,0.5*zfood) )
zdenom = zfoodlim / ( xkgraz + zfoodlim )
zdenom2 = zdenom / ( zfood + rtrn )
zgraze = grazrat * xstep * tgfunc2(ji,jj,jk) * tr(ji,jj,jk,jpzoo,Kbb) * (1. - nitrfac(ji,jj,jk))
! An active switching parameterization is used here.
! We don't use the KTW parameterization proposed by
! Vallina et al. because it tends to produce too steady biomass
! composition and the variance of Chl is too low as it grazes
! too strongly on winning organisms. We use a generalized
! switching parameterization proposed by Morozov and
! Petrovskii (2013)
! ------------------------------------------------------------
! The width of the selection window is increased when preys
! have low abundance, .i.e. zooplankton become less specific
! to avoid starvation.
! ----------------------------------------------------------
zsigma = 1.0 - zdenom**2/(0.05**2+zdenom**2)
zsigma = xsigma + xsigmadel * zsigma
zdiffdn = exp( -ABS(log(1.67 * sizen(ji,jj,jk) / (5.0 * sized(ji,jj,jk) + rtrn )) )**2 / zsigma**2)
ztmp1 = xprefn * zcompaph * ( zcompaph + zdiffdn * zcompadi ) / ( 1.0 + zdiffdn )
ztmp2 = xprefd * zcompadi * ( zdiffdn * zcompaph + zcompadi ) / ( 1.0 + zdiffdn )
ztmp3 = xprefc * zcompapoc**2
ztmptot = ztmp1 + ztmp2 + ztmp3 + rtrn
ztmp1 = ztmp1 / ztmptot
ztmp2 = ztmp2 / ztmptot
ztmp3 = ztmp3 / ztmptot
! Ingestion terms on the different preys of microzooplankton
zgraznc = zgraze * ztmp1 * zdenom ! Nanophytoplankton
zgrazdc = zgraze * ztmp2 * zdenom ! Diatoms
zgrazpoc = zgraze * ztmp3 * zdenom ! POC
! Ingestion terms on the iron content of the different preys
zgraznf = zgraznc * tr(ji,jj,jk,jpnfe,Kbb) / (tr(ji,jj,jk,jpphy,Kbb) + rtrn)
zgrazpof = zgrazpoc * tr(ji,jj,jk,jpsfe,Kbb) / (tr(ji,jj,jk,jppoc,Kbb) + rtrn)
zgrazdf = zgrazdc * tr(ji,jj,jk,jpdfe,Kbb) / (tr(ji,jj,jk,jpdia,Kbb) + rtrn)
!
! Total ingestion rate in C, Fe, N units
zgraztotc = zgraznc + zgrazpoc + zgrazdc
zgraztotf = zgraznf + zgrazdf + zgrazpof
zgraztotn = zgraznc * quotan(ji,jj,jk) + zgrazpoc + zgrazdc * quotad(ji,jj,jk)
! Grazing by microzooplankton
zgrazing(ji,jj,jk) = zgraztotc
! Microzooplankton efficiency.
! We adopt a formulation proposed by Mitra et al. (2007)
! The gross growth efficiency is controled by the most limiting nutrient.
! Growth is also further decreased when the food quality is poor. This is currently
! hard coded : it can be decreased by up to 50% (zepsherq)
! GGE can also be decreased when food quantity is high, zepsherf (Montagnes and
! Fulton, 2012)
! -----------------------------------------------------------------------------
zgrasratf = ( zgraztotf + rtrn ) / ( zgraztotc + rtrn )
zgrasratn = ( zgraztotn + rtrn ) / ( zgraztotc + rtrn )
zepshert = MIN( 1., zgrasratn, zgrasratf / feratz)
zbeta = MAX(0., (epsher - epshermin) )
! Food quantity deprivation of the GGE
zepsherf = epshermin + zbeta / ( 1.0 + 0.04E6 * 12. * zfood * zbeta )
! Food quality deprivation of the GGE
zepsherq = 0.5 + (1.0 - 0.5) * zepshert * ( 1.0 + 1.0 ) / ( zepshert + 1.0 )
! Actual GGE of microzooplankton
zepsherv = zepsherf * zepshert * zepsherq
! Excretion of Fe
zgrafer = zgraztotc * MAX( 0. , ( 1. - unass ) * zgrasratf - feratz * zepsherv )
! Excretion of C, N, P
zgrarem = zgraztotc * ( 1. - zepsherv - unass )
! Egestion of C, N, P
zgrapoc = zgraztotc * unass
! Update of the TRA arrays
! ------------------------
! Fraction of excretion as inorganic nutrients and DIC
zgrarsig = zgrarem * sigma1
tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + zgrarsig
tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zgrarsig
tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zgrarem - zgrarsig
!
IF( ln_ligand ) THEN
tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) + (zgrarem - zgrarsig) * ldocz
zzligprod(ji,jj,jk) = (zgrarem - zgrarsig) * ldocz
ENDIF
!
tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) - o2ut * zgrarsig
tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + zgrafer
zfezoo(ji,jj,jk) = zgrafer
tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zgrapoc
prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zgrapoc
tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + zgraztotf * unass
tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) + zgrarsig
tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zgrarsig
! Update the arrays TRA which contain the biological sources and sinks
! --------------------------------------------------------------------
zmortz = ztortz + zrespz
tr(ji,jj,jk,jpzoo,Krhs) = tr(ji,jj,jk,jpzoo,Krhs) - zmortz + zepsherv * zgraztotc
tr(ji,jj,jk,jpphy,Krhs) = tr(ji,jj,jk,jpphy,Krhs) - zgraznc
tr(ji,jj,jk,jpdia,Krhs) = tr(ji,jj,jk,jpdia,Krhs) - zgrazdc
tr(ji,jj,jk,jpnch,Krhs) = tr(ji,jj,jk,jpnch,Krhs) - zgraznc * tr(ji,jj,jk,jpnch,Kbb)/(tr(ji,jj,jk,jpphy,Kbb)+rtrn)
tr(ji,jj,jk,jpdch,Krhs) = tr(ji,jj,jk,jpdch,Krhs) - zgrazdc * tr(ji,jj,jk,jpdch,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn)
tr(ji,jj,jk,jpdsi,Krhs) = tr(ji,jj,jk,jpdsi,Krhs) - zgrazdc * tr(ji,jj,jk,jpdsi,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn)
tr(ji,jj,jk,jpgsi,Krhs) = tr(ji,jj,jk,jpgsi,Krhs) + zgrazdc * tr(ji,jj,jk,jpdsi,Kbb)/(tr(ji,jj,jk,jpdia,Kbb)+rtrn)
tr(ji,jj,jk,jpnfe,Krhs) = tr(ji,jj,jk,jpnfe,Krhs) - zgraznf
tr(ji,jj,jk,jpdfe,Krhs) = tr(ji,jj,jk,jpdfe,Krhs) - zgrazdf
tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zmortz - zgrazpoc
prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz
conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc
tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + feratz * zmortz - zgrazpof
!
! Calcite remineralization due to zooplankton activity
! part of the ingested calcite is not dissolving in the acidic gut
! ----------------------------------------------------------------
zprcaca = xfracal(ji,jj,jk) * zgraznc
prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
!
zprcaca = part * zprcaca
tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) - zprcaca
tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) - 2. * zprcaca
tr(ji,jj,jk,jpcal,Krhs) = tr(ji,jj,jk,jpcal,Krhs) + zprcaca
END_3D
!
IF( lk_iomput .AND. knt == nrdttrc ) THEN
IF( iom_use("GRAZ1") ) THEN ! Total grazing of phyto by zooplankton
zgrazing(:,:,jpk) = 0._wp ; CALL iom_put( "GRAZ1" , zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) )
ENDIF
IF( iom_use("FEZOO") ) THEN
zfezoo (:,:,jpk) = 0._wp ; CALL iom_put( "FEZOO", zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) )
ENDIF
IF( ln_ligand ) THEN
zzligprod(:,:,jpk) = 0._wp ; CALL iom_put( "LPRODZ", zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:))
ENDIF
ENDIF
!
IF(sn_cfctl%l_prttrc) THEN ! print mean trends (used for debugging)
WRITE(charout, FMT="('micro')")
CALL prt_ctl_info( charout, cdcomp = 'top' )
CALL prt_ctl(tab4d_1=tr(:,:,:,:,Krhs), mask1=tmask, clinfo=ctrcnm)
ENDIF
!
IF( ln_timing ) CALL timing_stop('p4z_micro')
!
END SUBROUTINE p4z_micro
SUBROUTINE p4z_micro_init
!!----------------------------------------------------------------------
!! *** ROUTINE p4z_micro_init ***
!!
!! ** Purpose : Initialization of microzooplankton parameters
!!
!! ** Method : Read the namp4zzoo namelist and check the parameters
!! called at the first timestep (nittrc000)
!!
!! ** input : Namelist namp4zzoo
!!
!!----------------------------------------------------------------------
INTEGER :: ios ! Local integer
!
NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xprefn, xprefc, &
& xprefd, xthreshdia, xthreshphy, xthreshpoc, &
& xthresh, xkgraz, epsher, epshermin, sigma1, unass, &
& xsigma, xsigmadel
!!----------------------------------------------------------------------
!
IF(lwp) THEN
WRITE(numout,*)
WRITE(numout,*) 'p4z_micro_init : Initialization of microzooplankton parameters'
WRITE(numout,*) '~~~~~~~~~~~~~~'
ENDIF
!
READ ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901)
901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zzoo in reference namelist' )
READ ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 )
902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist' )
IF(lwm) WRITE( numonp, namp4zzoo )
!
IF(lwp) THEN ! control print
WRITE(numout,*) ' Namelist : namp4zzoo'
WRITE(numout,*) ' part of calcite not dissolved in microzoo guts part =', part
WRITE(numout,*) ' microzoo preference for POC xprefc =', xprefc
WRITE(numout,*) ' microzoo preference for nano xprefn =', xprefn
WRITE(numout,*) ' microzoo preference for diatoms xprefd =', xprefd
WRITE(numout,*) ' diatoms feeding threshold for microzoo xthreshdia =', xthreshdia
WRITE(numout,*) ' nanophyto feeding threshold for microzoo xthreshphy =', xthreshphy
WRITE(numout,*) ' poc feeding threshold for microzoo xthreshpoc =', xthreshpoc
WRITE(numout,*) ' feeding threshold for microzooplankton xthresh =', xthresh
WRITE(numout,*) ' exsudation rate of microzooplankton resrat =', resrat
WRITE(numout,*) ' microzooplankton mortality rate mzrat =', mzrat
WRITE(numout,*) ' maximal microzoo grazing rate grazrat =', grazrat
WRITE(numout,*) ' non assimilated fraction of P by microzoo unass =', unass
WRITE(numout,*) ' Efficicency of microzoo growth epsher =', epsher
WRITE(numout,*) ' Minimum efficicency of microzoo growth epshermin =', epshermin
WRITE(numout,*) ' Fraction of microzoo excretion as DOM sigma1 =', sigma1
WRITE(numout,*) ' half saturation constant for grazing 1 xkgraz =', xkgraz
WRITE(numout,*) ' Width of the grazing window xsigma =', xsigma
WRITE(numout,*) ' Maximum additional width of the grazing window xsigmadel =', xsigmadel
ENDIF
!
END SUBROUTINE p4z_micro_init
!!======================================================================
END MODULE p4zmicro